home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 2000 #5 / Amiga Plus CD - 2000 - No. 5.iso / Tools / WWW / YAM / Rexx / GotoURL.yam < prev    next >
Encoding:
Text File  |  2000-01-01  |  2.3 KB  |  91 lines
  1. /* GotoURL.yam - Passes URL's from YAM to a web browser             */
  2. /* $VER: GotoURL.yam 1.3 (25.02.00) © 2000 by M.Beck <mbeck@yam.ch> */
  3. /* based on Harry Samwels <samwel@algonet.se> script                */
  4. /* Tested with IBrowse 1.2, Voyager 2.95 and AWeb 3.1               */
  5. /*                                                                  */
  6. /* Call this script from                                            */
  7. /* YAM/Configuration/ARexx/When double-clicking an URL              */
  8.  
  9. /* Use Miami to go online if necessary (1=yes) */
  10. UseMiami=1
  11.  
  12. /* Path and filename of Miami */
  13. MiamiPath = "MIAMI:Miami"
  14.  
  15. /* Path and filename of your default browser */
  16. BrowserPath='Prog:Internet/IBrowse/IBrowse'
  17.  
  18. /* Default browser (possible inputs: IBrowse, Voyager and AWeb) */
  19. UsedBrowser='IBrowse'
  20.  
  21. /* Load URL in a new window (1=yes) */
  22. NewWindow=1
  23.  
  24. /* Use running browser if available (1=yes) */
  25. AutoBrowser=1
  26.  
  27. /* ----------------------- DON'T EDIT BELOW THIS LINE ---------------------- */
  28.  
  29. OPTIONS RESULTS
  30. OPTIONS FAILAT 21
  31.  
  32. PARSE ARG URL
  33.  
  34. UB = UPPER(UsedBrowser)
  35. rxports=SHOW('P')
  36. IF AutoBrowser=1 THEN DO
  37.   IF SHOW('P','IBROWSE') THEN UB='IBROWSE'
  38.   ELSE IF SHOW('P','VOYAGER') THEN UB='VOYAGER'
  39.   ELSE IF INDEX(rxports,'AWEB')>0 THEN UB='AWEB'
  40. END
  41. SELECT
  42.   WHEN UB='IBROWSE' THEN port='IBROWSE'
  43.   WHEN UB='VOYAGER' THEN port='VOYAGER'
  44.   WHEN UB='AWEB' THEN DO
  45.     PARSE VAR rxports dummy 'AWEB.' portnr .
  46.     IF portnr = '' THEN portnr = 1
  47.     port='AWEB.' || portnr
  48.   END
  49.   OTHERWISE EXIT 10
  50. END
  51. ADDRESS COMMAND
  52. IF ~SHOW('P',port) THEN DO
  53.   NewWindow = 0
  54.   'RUN >NIL:' browserpath
  55.   'SYS:rexxc/WaitForPort' port
  56.   IF RC>0 THEN DO
  57.      ADDRESS YAM 'REQUEST "'usedbrowser' not found.\nPlease install 'usedbrowser' or change the script configuration!" "Okay!"'
  58.      EXIT 5
  59.   END
  60. END
  61. IF UseMiami=1 THEN DO
  62.    IF ~SHOW('P', 'MIAMI.1') THEN DO
  63.      'Run <>NIL:' miamipath
  64.      'WaitForPort MIAMI.1'
  65.    END
  66.    ADDRESS 'MIAMI.1'
  67.    ISONLINE
  68.    IF RC=0 THEN ONLINE
  69.    ISONLINE
  70.    IF RC=0 THEN EXIT 5
  71.    HIDE
  72. END
  73. INTERPRET 'ADDRESS' port
  74. SELECT
  75.   WHEN UB='IBROWSE' THEN DO
  76.     IF NewWindow=1 THEN 'NewWindow 'url
  77.                    ELSE 'GotoURL 'url
  78.   END
  79.   WHEN UB='VOYAGER' THEN DO
  80.     IF NewWindow=1 THEN 'OpenURL 'url' NEWWIN'
  81.                    ELSE 'OpenURL 'url
  82.   END
  83.   WHEN UB='AWEB' THEN DO
  84.     IF NewWindow=1 THEN 'New 'url
  85.                    ELSE 'Open 'url
  86.   END
  87. END
  88. EXIT
  89.  
  90.  
  91.